Winforms OK / Cancel processing

Tips for using the winforms' built-in modal dialog boxes support

These properties affect what happens when you press Enter or Escape while the form has the focus - pressing Enter acts as if you had clicked the button set in the AcceptButton property, and pressing Escape acts as if you'd clicked the button in the CancelButton property.

To make it easier for you to create MessageBox-like forms, Visual Studio .NET provides a DialogResult property for each button on the form. If you use the ShowDialog method of a form to display the form modally, click a button on the form that has its DialogResult property set, the return value from the ShowDialog method (you can also retrieve the form's DialogResult property, at run time) will contain the DialogResult property value of the button you clicked. Once you've set the DialogResult property for a button, clicking that button will close the dialog form, so you needn't write that code explicitly.

But what if I want to do some validation WITHIN the button's Click event handler and if the validation fails, I DON'T WANT to close the dialog?

As an example, take the UserLogonDialog (discussed in the article .NET Interception). Here is the Click event handler code:

Private Sub OKCmd_Click( _
  ByVal sender As System.Object, _
  ByVal e As System.EventArgs) Handles OKCmd.Click
	
  Try
    If Not App.LogonUser(UserName.Text, Password.Text) Then
      Password.Text = String.Empty
      UserName.Select()
      MsgBox("Invalid logon or password. Try again.", MsgBoxStyle.Exclamation)
    End If
  Catch ex As Exception
    MsgBox(ex.Message, MsgBoxStyle.Exclamation)
  End Try
End Sub

First solution: Set OKCmd.DialogResult = DialogResult.None (string "None" in the designer) and close the form manually:

Private Sub OKCmd_Click( _
  ByVal sender As System.Object, _
  ByVal e As System.EventArgs) Handles OKCmd.Click
	
  Try
    If Not App.LogonUser(UserName.Text, Password.Text) Then
      Password.Text = String.Empty
      UserName.Select()
      MsgBox("Invalid logon or password. Try again.", MsgBoxStyle.Exclamation)
    Else
      Me.DialogResult = DialogResult.OK
      Me.Close()
    End If
  Catch ex As Exception
    MsgBox(ex.Message, MsgBoxStyle.Exclamation)
  End Try
End Sub

Public Class UserLogonDialog
  Inherits System.Windows.Forms.Form

  ' Signal the Closing event handler whether the form's
  ' closure should be canceled.
  Private _CancelClose As Boolean
...

Private Sub OKCmd_Click( _
  ByVal sender As System.Object, _
  ByVal e As System.EventArgs) Handles OKCmd.Click
  Try
    If Not App.LogonUser(UserName.Text, Password.Text) Then
      Password.Text = String.Empty
      UserName.Select()
      MsgBox("Invalid logon or password. Try again.", MsgBoxStyle.Exclamation)
      _CancelClose = True
    End If
  Catch ex As Exception
    MsgBox(ex.Message, MsgBoxStyle.Exclamation)
  End Try
End Sub
...
Private Sub UserLogonForm_Closing( _
  ByVal sender As Object, _
  ByVal e As CancelEventArgs) Handles MyBase.Closing
  
  e.Cancel = _CancelClose
  _CancelClose = False
End Sub

I've been using the second solution until now, but I'll switch to the first one eventually – it is simpler and more maintainable.

(I'd appreciate some kind of Form.CancelAutoClose property, however ).